This tutorial was completed using ANSYS 7.0 The purpose of the tutorial is to describe how to utilize contact elements to simulate how two beams react when they come into contact with each other.

The beams, as shown below, are 100mm long, 10mm x 10mm in cross-section, have a Young's modulus of 200 GPa, and are rigidly constrained at the outer ends. A 10KN load is applied to the center of the upper, causing it to bend and contact the lower.

ANSYS Command Listing

finish
/clear

/title,Contact Elements
/prep7

! Top Beam
X1=0
Y1=15
L1=100
H1=10

! Bottom Beam
X2=50
Y2=0
L2=100
H2=10

! Create Geometry
blc4,X1,Y1,L1,H1
blc4,X2,Y2,L2,H2

! define element type

ET,1,plane42	    ! element type 1
keyopt,1,3,3        ! plane stress w/thick 
type,1              ! activate element type 1
R, 1, 10            ! thickness 0.01   

! define material properties

MP,EX,  1, 200e3    ! Young's modulus
MP,NUXY,1, 0.3      ! Poisson's ratio

! meshing

esize,2             ! set meshing size
amesh,all           ! mesh area 1

ET,2,contac48       ! defines second element type - 2D contact elements
keyo,2,7,1	    ! contact time/load prediction
r,2,200000,,,,10
TYPE,2              ! activates or sets this element type
real,2		    ! activates or sets the real constants

! define contact nodes and elements

! first the contact nodes
asel,s,area,,1           ! select top area
nsla,s,1                 ! select the nodes within this area
nsel,r,loc,y,Y1          ! select bottom layer of nodes in this area
nsel,r,loc,x,X2,(X2+L2/2)! select the nodes above the other beam
cm,source,node           ! call this group of nodes 'source'

! then the target nodes
allsel                   ! relect everything
asel,s,area,,2           ! select bottom area
nsla,s,1                 ! select nodes in this area
nsel,r,loc,y,H2          ! select bottom layer of nodes in this area
nsel,r,loc,x,X2,(X2+L2/2)! select the nodes above the other beam
cm,target,node           ! call this selection 'target'

gcgen,source,target,3    ! generate contact elements between defined nodes

finish
/solut
antype,0

time,1			! Sets time at end of run to 1 sec
autots,on		! Auto time-stepping on
nsubst,100,1000,20	! Number of sub-steps
outres,all,all		! Write all output
neqit,100		! Max number of iterations

nsel,s,loc,x,X1		! Constrain top beam
nsel,r,loc,y,Y1,(Y1+H1)
d,all,all
nsel,all

nsel,s,loc,x,(X2+L2)	! Constrain bottom beam
nsel,r,loc,y,Y2,(Y2+H2)
d,all,all
nsel,all

nsel,s,loc,x,(L1/2+X1)	! Apply load
nsel,r,loc,y,(Y1+H1)
f,all,fy,-10000
nsel,all

solve
finish

/post1
/dscale,1,1
/CVAL,1,20,40,80,160,320,640,1280,2560
PLNSOL,S,EQV,0,1