This tutorial was completed using ANSYS 7.0 The purpose of the tutorial is to show the how to use substructuring in ANSYS. Substructuring is a procedure that condenses a group of finite elements into one super-element. This reduces the required computation time and also allows the solution of very large problems.

A simple example will be demonstrated to explain the steps required, however, please note that this model is not one which requires the use of substructuring. The example involves a block of wood (E =10 GPa v =0.29) connected to a block of silicone (E = 2.5 MPa, v = 0.41) which is rigidly attached to the ground. A force will be applied to the structure as shown in the following figure. For this example, substructuring will be used for the wood block.

The use of substructuring in ANSYS is a three stage process:

1. Generation Pass
   Generate the super-element by condensing several elements together. Select the degrees of freedom to save (master DOFs) and to discard (slave DOFs). Apply loads to the super-element

2. Use Pass
   Create the full model including the super-element created in the generation pass. Apply remaining loads to the model. The solution will consist of the reduced solution tor the super-element and the complete solution for the non-superelements.

3. Expansion Pass
   Expand the reduced solution to obtain the solution at all DOFs for the super-element.

Note that a this method is a bottom-up substructuring (each super-element is created separately and then assembled in the Use Pass). Top-down substructuring is also possible in ANSYS (the entire model is built, then super-element are created by selecting the appropriate elements). This method is suitable for smaller models and has the advantage that the results for multiple super-elements can be assembled in postprocessing.

ANSYS Command Listing

! Bottom-Up Substructuring

! GENERATION PASS - Build the superelement portion of the model
FINISH
/CLEAR, START 
/FILNAME,GEN			! Change jobname 

/PREP7

! Create Geometry  
blc4,0,40,100,100		! Creates rectangle

! Define material properties of wood section
ET,1,PLANE42        		! Element type
MP,EX,1, 10000      		! Young's Modulus
MP,PRXY,1,0.29 			! Poisson's ratio

! meshing
AESIZE,1,10, 			! Element size
amesh,1				! Mesh area

FINISH
/SOLU

ANTYPE,SUBST              	! SUBSTRUCTURE GENERATION PASS
SEOPT,GEN,,2			! Name = GEN and no printed output

NSEL,S,EXT     		        ! Select all external nodes
M,ALL,ALL			! Make all selected nodes master DOF's
NSEL,ALL			! Reselect all nodes

NSEL,S,LOC,Y,140		! Select the corner node
NSEL,R,LOC,X,0
F,ALL,FX,5			! Load it

NSEL,ALL			! Reselect all nodes

SAVE                  		! Saves file to jobname.db
SOLVE 		                ! GEN.SUB created
FINISH

! USE PASS
FINISH
/CLEAR
/FILNAME,USE			! Change jobname to use
/PREP7

! Create Geometry of non superelements  
blc4,0,0,100,40			! Creates rectangle

! Define material properties
ET,2,PLANE42			! Element type
TYPE,2				! Turns on element type 2
MP,EX,2, 2.5			! Second material property set for silicon
MP,PRXY,2,0.41

! Meshing
AESIZE,1,10, 			! Element size
mat,2				! Turns on Material 2
real,2				! Turns on real constants 2
amesh,1				! Mesh the area

! Superelement 
ET,1,MATRIX50		        ! MATRIX50 is the superelement type
TYPE,1				! Turns on element type 1
*GET,MaxNode,NODE,,NUM,MAX      ! determine the max number of nodes
SETRAN,GEN,,MaxNode,GEN2        ! node number offset
SE,GEN2                         ! Read in superelement matrix
NSEL,S,LOC,Y,40                 ! Select nodes at interface
CPINTF,ALL                      ! Couple node pairs at interface
NSEL,ALL

FINISH

/SOLU
ANTYPE,STATIC			! Static analysis

NSEL,S,LOC,Y,0			! Select all nodes at y = 0
D,ALL,ALL,0			! Constrain those nodes
NSEL,ALL			! Reselect all nodes

ESEL,S,TYPE,,1			! Element select
SFE,ALL,1,SELV,,1		! Apply super-element load vector
ESEL,ALL			! Reselect all elements

SAVE
SOLVE
FINISH

/POST1 				! Enter post processing
PLNSOL,U,SUM,0,1  		! Plot deflection contour
FINISH

! EXPANSION PASS
/CLEAR              		! Clear database
/FILNAME,GEN        		! Change jobname back to generation pass jobname
RESUME  	            	! Restore generation pass database
	
/SOLU  		                ! Enter SOLUTION
EXPASS,ON,YES   		! Activate expansion pass
SEEXP,GEN2,USE   		! Superelement name to be expanded
EXPSOL,1,1,			! Expansion pass info
SOLVE        		        ! Initiate expansion pass solution.  Full superelement solution written to GEN.RST
FINISH
  
/POST1 
PLNSOL,U,SUM,0,1  		! Plot deflection contour