Problem Description

ANSYS Command Listing

/PREP7
/TITLE, RADIATION HEAT TRANSFER BETWEEN CONCENTRIC CYLINDERS
ANTYPE,STATIC

! this is a general version of VM125 converted to metric

rin=2*0.0254             ! inches to metres
rout=8*0.0254
ndiv=20
arc=360
emis1=0.7
emis2=0.5
T1=700                   ! degrees C
T2=400
offset=273               ! to convert to degrees K
stefbolt=5.699*10**(-8)  ! metric version

k,1,0,0                  ! center of tube 1
k,5,0,0                  ! center of retort

k,6,0,0,-1
k,7,1
k,8,0,0,1

circle,1,rin,6,7,arc,ndiv      ! inner cylinder, generated clockwise
CIRCLE,5,rout,8,7,arc,ndiv     ! outer cylinder; generated counter-clockwise

ET,1,LINK32,,,,,,,1    ! HEAT CONDUCTING BAR; SUPPRESS SOLUTION OUTPUT
R,1,1                  ! UNIT CROSS-SECTIONAL AREA (ARBITRARY)

MP,KXX,1,1             ! CONDUCTIVITY of inner cylinder (arbitrary)
MAT,1
ESIZE,,1
csys,1                 ! cylindrical coord system
lsel,s,loc,x,rin
LMESH,ALL
lsel,all

MP,KXX,2,1             ! CONDUCTIVITY of outer cylinder (arbitrary)
MAT,2
lsel,s,loc,x,rout
LMESH,all
lsel,all
csys,0                 ! reset to rect coord system
FINISH

/AUX12
EMIS,1,emis1
EMIS,2,emis2
VTYPE,0                ! HIDDEN PROCEDURE FOR VIEW FACTORS
GEOM,1                 ! GEOMETRY SPECIFICATION 2-D
STEF,stefbolt          ! Stefan-Boltzmann constant
WRITE,VM125            ! WRITE RADIATION MATRIX TO FILE VM125.SUB
FINISH

/PREP7
DOF,TEMP
ET,2,MATRIX50,1,,,,,1  ! SUPERELEMENT (RADIATION MATRIX)
TYPE,2
SE,VM125               ! defines superelement and where its written to
TOFFST,offset          ! TEMPERATURE OFFSET FOR ABSOLUTE SCALE
csys,1
nsel,s,loc,x,rout      ! SELECT OUTER CYLINDER NODES
D,ALL,TEMP,T1          ! T1 = 273 + 700 DEG. K
nsel,all

nsel,s,loc,x,rin       ! SELECT INNER CYLINDER NODES
D,ALL,TEMP,T2          ! T2 = 273 + 400 DEG. K
nsel,all
csys,0
FINISH

/SOLU
SOLVE
FINISH

/POST1
csys,1
nsel,s,loc,x,rin       ! SELECT INNER CYLINDER NODES
/com
/COM,:) :) heat flow from inner to outer :) :)
/com
PRRSOL                 ! PRINT HEAT FLOW FROM INNER TO OUTER CYLINDER

nsel,all
nsel,s,loc,x,rout      ! select outer cylinder nodes
/com
/COM,:) :) heat flow from outer to inner :) :)
/com
PRRSOL                 ! PRINT HEAT FLOW FROM OUTER TO INNER CYLINDER

FSUM,HEAT              ! only from selected nodes !!!
nsel,all
*GET,Q,FSUM,0,ITEM,HEAT
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'Q(W/m)  ' ! the 1 below is for unit length
numer=stefbolt*2*pi*rin*1*((offset+T1)**4-(offset+T2)**4)
exact=numer/(1/emis1+(rin/rout)*(1/emis2-1))
*VFILL,VALUE(1,1),DATA,exact
*VFILL,VALUE(1,2),DATA,Q
*VFILL,VALUE(1,3),DATA,ABS(Q/exact)
/COM
/COM,--------------- VM125 RESULTS COMPARISON --------------
/COM,
/COM,           |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,'   ',F10.1,'  ',F10.1,'       ',1F5.3)
/COM,-------------------------------------------------------
/COM,
FINISH